#define ASM_SOURCE 1
.file "irq_wrappers.S"
.text

.extern interrupt_handler_pic
.globl irq_handler_wrapper_array

.altmacro


.macro interrupt_pic irq
    int_wrapper_\irq:
    .type int_wrapper_\irq,@function
        /* INTERRUPT FRAME START */
        /* ALREADY PUSHED TO US BY THE PROCESSOR UPON ENTRY TO THIS INTERRUPT */
        /* uint32_t ip */
        /* uint32_t cs; */
        /* uint32_t flags */
        /* Pushes the other reg to save same and look like a struct cpu_state*/
        /* Fake error code */
		pushl $0

		/* Backup the actual context */
		pushl %ebp
		movl %esp, %ebp

		pushl %edi
		pushl %esi
		pushl %edx
		pushl %ecx
		pushl %ebx
		pushl %eax
		subl  $2,%esp
		pushw %ss
		pushw %ds
		pushw %es
		pushw %fs
		pushw %gs

        push %esp
        pushl $\irq
        call interrupt_handler_pic
        addl $8, %esp

		/* Restore the context */
		popw  %gs
		popw  %fs
		popw  %es
	        popw  %ds
		popw  %ss
		addl  $2,%esp
		popl  %eax
		popl  %ebx
		popl  %ecx
		popl  %edx
		popl  %esi
		popl  %edi
		popl  %ebp

		/* Remove fake error code */
		addl  $4, %esp

        iret
.endm


.set i, 0
.rept 0x10
    interrupt_pic %i
    .set i, i+1
.endr

.macro ref_int_wrapper irq
    .long int_wrapper_\irq
.endm

.section ".rodata"
.p2align 5, 0x0
irq_handler_wrapper_array:
.set i, 0x0
.rept 0x10
    ref_int_wrapper %i
    .set i, i+1
.endr